비와바람이 함께하는 세상속으로..

델마당의 장성호님의 답변해 주신 글입니다.. (물론 제 질문은 아닙니...)

http://www.delmadang.com/community/bbs_view.asp?bbsNo=17&bbsCat=41&indx=409079&keyword1=Hint&keyword2=시간

------------------------------------------------------------------------------


ListView에서 Row별로  힌트를 다르게 주려고 한다면

MouseMove 이벤트에 처리해야 하는것은 맞습니다.


1. 먼저 OnMouseMove이벤트에서 현재 마우스 위치에 Row 즉 ListItem을 알아야 겠죠?

    그것은 ListView에 GetItemAt 이라는 함수가 있습니다.
 
   procedure TForm3.ListView1MouseMove(Sender: TObject; Shift: TShiftState; X,  Y: Integer);
   var
      item: TListItem;
    begin
       item:=ListView1.GetItemAt(X,Y);
       ....
   end;

   문론 GetItemAt으로 item을 구했는데 nil 인경우도 있습니다. 
   이럴경우도 처리해야죠

2. Mouse위치의 Item을 알았으니 ListView의 Hint를 바꿔줘야 겠죠
    다음과 같이 마우스 위치의 ListItem을 구해서 ListView의 Hint를 바꿔줄수 있습니다.
 

procedure TForm3.ListView1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
var
  item: TListItem;
begin
  item:=ListView1.GetItemAt(X,Y);

  if Assigned(item)then
  begin
      ListView1.Tag:= item.Index ;
      ListView1.Hint:='ListView Items= '+item.Caption;
  end
......
end;
 

     그런데 Hint를 바꾼다고 해서 바로 변경된 Hint가 보여지는것이 아니죠

3.  Hint를 보여주고/ 말고 하는것은 Application객체가 담당합니다.
     
     대게 Hint가 보여지는것은 마우스위치에 있는 Control이 바뀌었을때 해당Control의 힌트를 보여주죠

      그런데 listview에서 mouse만을 움직였을때는 item만 바뀌지 control을 여전히 같은 listview이기때문에
      hint가 보여지지 않는것입니다.


4. 즉각적으로 Hint를 다시 보여주려면 Application의 Hint관련 함수를 이용하면 됩니다.
 
    // 현재 떠있는 힌트를 닫습니다.
    Application.CancelHint;    
  
    // 넘겨준 TPoint위치에 hint를 보여줍니다.
   Application.ActivateHint( point );

5. 결론적으로 listveiw의 hint를 바꾼뒤에
     위 Application 의 CancelHint  , ActivateHint 를 한번씩 호출해주면 됩니다.
 

procedure TForm3.ListView1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
var
  item: TListItem;
begin
  item:=ListView1.GetItemAt(X,Y);

  if Assigned(item)then
  begin
      ListView1.Hint:='ListView Items= '+item.Caption;
      Application.CancelHint;
      Application.ActivateHint(Mouse.CursorPos);
  end;
end;
 

6. 그러데 MouseMove 이벤트가 같은 item위치에서 여러번 발생할수있죠
    마우스위치의 item이 바뀌지 않았는데 반복해서 CancelHint , ActivateHint 를 띄우면
    좀 이상하겠쬬

    그러니 현재 hint로 띄운 item을 기억하고 있을 필요가 있을것입니다.
    
   즉 item이 변경되면 hint를 새로 띄우는것이 아니라
    hint가 변경되면 hint를 새로띄우는것이죠

procedure TForm3.ListView1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var
  item: TListItem;
begin
  item:=ListView1.GetItemAt(X,Y);

  if Assigned(item)then
  begin
    if(item.Index <>ListView1.Tag ) then
    begin
      //item의 index를 ListView.Tag에 기억해두고 tag가 같지 않는경우에만 ...
      ListView1.Tag:= item.Index ;
      ListView1.Hint:='ListView Items= '+item.Caption;
      Application.CancelHint;
      Application.ActivateHint(Mouse.CursorPos);
    end;
  end;
end;   

     뭐 대충 이런식으로 하면 됩니다.

     이 방식으로 listview뿐만 아니라 VCL의 모든 Control에 적용할수 있습니다.
     마우스 위치의 control이 변경되지 않았는데
     hint를 바꾸고 싶을경우에는 

     1)  먼저 hint를 바꾼후에
     2)  Application.CancelHint;
     3)  Application.ActivateHint(Mouse.CursorPos);
       해주면 됩니다.
    
6. 마지막으로  Application 객체에는 hint관련해서 프로퍼티와 함수가 몇가지 더 있습니다.

      Application.Hint;
      Application.HintColor:=clRed;  //힌트 보여지는 Color
      Application.HintPause; //Control위에 마우스가 들어간뒤에 Hint가 보여지기까지 delay
      Application.HintHidePause; //hint가 나타난후에 사라지기까지 시간
      Application.HintShortCuts;
      Application.HintShortPause;

7.  hint를 좀더 발전된 형태로 보여주고 싶다면

     THintWindow 를 상속받아서 hint 클래스를 새로만드시구요   
     TMyHintWindow = class(THintwindow) 
   
     다음과 같이 HintWindowClass 에 설정해주시면
     HintWindowClass := TMyHintWindow
     Application객체가 HintWindowClass 에 등록된 class를 생성해서 보여줍니다.

그럼..

Delphi 2007에서는 Tee Chart와 QuickReport가 연동되지 않는다.

퀵리포트를 pro버전 사면 되는거 같긴 한데, 확실치는 않고..

그래서 델마당에 문의한 결과, metaFile로 받아서 이미지로 출력하는 방법을 얻어냈다.

(대단하신 분이다.. ^^)

그걸 내 입맛에 맞게 조금 수정했다.

procedure TfrmChartPrt.qrpChartLandScapeBeforePrint(Sender: TCustomQuickRep;
  var PrintReport: Boolean);
var
    mtMeta      : TMetaFile;
    alAlign : TAlign;
begin
    alAlign := gchtChart.Align;  //속성백업
    gchtChart.Align := alnone;  //속성을 초기화 한다.

    gchtChart.Width    := qimgLandScape.Width;
    gchtChart.Height   := qimgLandScape.Height;

    mtMeta  := gchtChart.TeeCreateMetafile(TRUE, gchtChart.GetRectangle);

    qimgLandScape.Picture.Metafile.Assign(mtMeta);

    gchtChart.Align := alAlign;  //백업된 속성을 복구한다.
end;

VCL에서 ShowMessage나 MessageDlg는 모두
TForm을 상속받은 TMessageForm을 생성해서 ShowModal로 띄워 주는것입니다.


TMessageForm클래스를 개발자에게 노출되어 있지는 않지만
CreateMessageDialog 라는 함수를 통해 생성할수 있습니다.

CreateMessageDialog 라는 함수를 이용하여 다음과 같이 다양하게 MessageBox의 기능을 변경해 보았습니다.

님께서 원하시는것은 아래에 있는것중 MessageDlgEx 일듯 하네요

//============================================================================

//메세지박스의 Title을 변경
procedure ShowMessageEx(const sTitle:String;const sMsg:String);
begin
  with CreateMessageDialog(sMsg, mtCustom, [mbOK]) do
    try
      Caption:=sTitle;
      HelpContext := 0;
      Position := poScreenCenter;
      ShowModal;
    finally
      Free;
    end;
end;

//메세지박스의 SystemMenu를 없앰
procedure ShowMessageEx2(const sMsg:String);
begin
  with CreateMessageDialog(sMsg, mtCustom, [mbOK]) do
    try
      BorderIcons:=[];
      HelpContext := 0;
      Position := poScreenCenter;
      ShowModal;
    finally
      Free;
    end;
end;

//MessageDlg함수의  SystemMenu없앰
function MessageDlgEx(const Msg: string; DlgType: TMsgDlgType;
  Buttons: TMsgDlgButtons; HelpCtx: Longint): Integer;
begin
 with CreateMessageDialog(Msg, DlgType, Buttons) do
    try
      HelpContext := 0;
      HelpFile := '';
      Position := poScreenCenter;
      BorderIcons:=[];
     Result :=  ShowModal;
    finally
      Free;
    end;
end;

//사용예..
procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessageEx('타이틀','메세지 입니다. 타이틀이 바뀌었나요?');
  //-----------------------
  ShowMessageEx2('X 아이콘이 안보이죠?');

  if MessageDlgEx('수정하시겠습니까?',mtConfirmation, [mbYes, mbNo], 0) = mrNo then  Exit;

end;

델마당에서..

http://www.delmadang.com/community/bbs_view.asp?bbsNo=17&bbsCat=0&st=&keyword=&indx=415548&keyword1=&keyword2=&page=1

1. 주석을 단 사람으로 이니셜을 쓰지 말자.

이게 이니셜을 쓰는 사람도 있고, 자기 아이디를 쓰는 사람도 있고 천차만별이다. 그런데, 가끔 보다보면 이게 이니셜등인지, 아니면 잘못친건지 구분이 안되는 인간들이 있다는 문제가...

가장 좋은게 자기 이름이다..


2. 가능하면 주석과 같이 작성한 일자도 기록하자.

특히 대단위 업데이트 작업을 하다보면 주석에 날짜를 넣는게 좋을때가 꽤 있다..


3. 소스 복사시 주석의 작성자 이니셜과 날짜는 없애라.

이거.. 꽤 문제가 생길때가 있다. 내가 한 3년전에 해놓은 건데, 누가 그걸 통째로.. 주석까지 카피를 해서 작업했는데, 그게 문제가 생겼다면... 괜하 나한테 와서 뭐라 그런다. -.-;
내가 한게 아니란 말이지...

설명이야 그냥 써도 상관없겠지만, 원작자, 작성일자등은 그냥 없애라...

Copy Right가 아니라 Copy Left다.. -.-;;